空间占用6个G怎么清理？

wuerbuzuo · 发表于 2025-4-17 10:35:48

占用空间有点多，试过浏览器自带的清理，没用

gh0ul · 发表于 2025-4-17 10:58:08

自带的wipe.bat，最新版的，旧版可能有些毛病

coult3 · 发表于 2025-4-18 12:02:57

可以参考（已解决）Service Worker目录可清空吗？ - 建议反馈 - 百分浏览器论坛 - Powered by Discuz!

如果不放心，可以备份整个 User Data 文件夹，比如放到U盘里，然后删除 Service Worker 目录，重启cent看看数据没丢失就可以。

JDF2008 · 发表于 2025-4-23 22:17:09

我的百分清理后只占520M空间。
CacheStorage
ScriptCache
IndexedDB
Code Cache
这几个目录下的文件都可以删除

q875720344 · 发表于 2025-4-24 12:06:11

本帖最后由 q875720344 于 2025-10-29 12:13 编辑

@echo off
setlocal enabledelayedexpansion
set "dsa=User Data"
set "dsb=Data"
set "dsc=FontLookupTableCache"
set "dsd=jav 115.com subtitlecat.com aliyundrive.com alipan.com masterzzz.site"
if exist "%dsa%" (
set "jxb=%dsa%"
) else if exist "%dsb%" (
set "jxb=%dsb%"
) else (
set "jxb=浏览器的 %dsa% 或者 %dsb%"
)
:loop
if not exist "%jxb%" (
mode con cols=70 lines=10
echo 位置存放正确的话，本提示就不会出现
echo 请把本程序放在跟 "%jxb%" 文件夹同一个目录上
pause
exit
)
dir /a-d /b "%jxb%" | findstr "^" >nul
if %errorlevel% == 1 (
mode con cols=40 lines=10
echo.
echo.
echo 你的数据文件夹 %jxb% 是空的
echo.
echo 本次不执行清理操作
echo.
echo.
pause
exit
) else (
mode con cols=35 lines=10
)
set "found=0"
set "obj="
for %%d in ("%jxb%") do (set "exe=%%~dpd")
set "jxb_exe=%exe:~0,-1%"
for %%f in ("%jxb_exe%") do (set "jxb_exe=%%~nxf")
set "jxb_exea=%jxb_exe%.exe"
set "jxb_zcb=HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\%jxb_exea%"
set "jxb_exec=0"
for %%p in (*.exe) do (
set "jxb_exec=1"
goto CheckExe
)
:CheckExe
if "!jxb_exec!" == "0" (
reg query "%jxb_zcb%" /v "Path" 2>nul | findstr /i "Path" >nul
if %errorlevel% == 0 (
for /f "tokens=2*" %%i in ('reg query "%jxb_zcb%" /v "Path" ^| findstr /i "Path"') do (
if not "%%j"=="" (
pushd "%%j" 2>nul && (
for /r %%e in (*.exe) do (
set "jxb_exed=%%~nxe"
tasklist | findstr /i "!jxb_exed!" >nul
if !errorlevel! == 0 (
echo.
echo.
echo 正在关闭 !jxb_exed! 进程...
echo.
echo.
taskkill /f /t /im "!jxb_exed!" >nul 2>&1
set "found=1"
)
)
popd
)
)
)
)
for %%e in ("%SystemDrive%\Program Files\Tencent" "%APPDATA%") do (
if exist "%%e\%jxb_exe%" (
for /r "%%e\%jxb_exe%" %%i in (*.exe) do (
set "jxb_exed=%%~nxi"
tasklist | findstr /i "!jxb_exed!" >nul
if !errorlevel! == 0 (
echo.
echo.
echo 正在关闭 !jxb_exed! 进程...
echo.
echo.
taskkill /f /t /im "!jxb_exed!" >nul 2>&1
set "found=1"
)
)
)
)
if defined jxb_exea (
tasklist | findstr /i "%jxb_exea%" >nul
if !errorlevel! == 0 (
echo.
echo.
echo 正在关闭 %jxb_exea% 进程...
echo.
echo.
taskkill /f /t /im "%jxb_exea%" >nul 2>&1
call :WaitForProcess %jxb_exea% >nul 2>&1
set "found=1"
) else (
goto exe_taskkill
)
) else (
goto exe_taskkill
)
)
:exe_taskkill
for /r %%p in (*.exe) do (
set "jxb_exee=%%~nxp"
tasklist | findstr /i "!jxb_exee!" >nul
if !errorlevel! == 0 (
echo.
echo.
echo 正在关闭 !jxb_exee! 进程...
echo.
echo.
taskkill /f /t /im "!jxb_exee!" >nul 2>&1
set "found=1"
)
)
if "!found!" == "0" (goto CLSUserDate)
goto :loop
:CLSUserDate
echo.
echo.
echo 数据目录是 "%jxb%" 文件夹
echo.
echo 正在清理浏览器垃圾中.....
echo.
echo 此清理过程可能需要一定时间
echo.
rd /s /q "User Data(SafeMode)" >nul 2>&1
del /a /f /q "*.tmp" "*.bak" "*.log" "*.old" "*-journal" "MANIFEST-*" "%jxb%\*.tmp" "%jxb%\*.bak" "%jxb%\*.log" "%jxb%\*.old" "%jxb%\*Cache" "%jxb%\*-journal" "%jxb%\MANIFEST-*" >nul 2>&1
for /d /r "%jxb%" %%i in (*Cache*) do (echo %%i | findstr /i "Cache[0-9]" >nul && if !errorlevel! == 0 rd /s /q "%%i" >nul 2>&1)
for /d %%i in ("%~dp0Cache*" "%~dp0*Cache" "%jxb%\Cache*" "%jxb%\*Cache") do (set "Cachea=%%~nxi" & set "Cacheb=0" & for %%e in (%dsc%) do if "!Cachea!"=="%%e" set "Cacheb=1") & if "!Cacheb!"=="0" rd /s /q "%%i" >nul 2>&1
for /d %%i in (*) do (set "Cachea=%%i" & if "!Cachea:~0,1!" geq "0" if "!Cachea:~0,1!" leq "9" (echo "!Cachea!" | findstr /r "\." >nul && (cd "%%i" && (for /d /r %%j in (*Cache*) do (set "Cacheb=%%~nxj" & set "Cachec=0" & for %%e in (%dsc%) do (if "!Cacheb!"=="%%e" set "Cachec=1")) & if "!Cachec!"=="0" (rd /s /q "%%j" >nul 2>&1)) & cd ..)))
for %%A in ("BrowserMetrics" "BrowserMetrics-spare.pma" "Crashpad" "CrashpadMetrics-active.pma" "DesktopSharingHub" "Floc" "Local Traces" "Mobile" "RecoveryImproved" "Service State" "Safe Browsing" "SwReporter" "UrlParamClassifications" "Webstore Downloads" "chrome_shutdown_ms.txt" "first_party_sets.db" "persisted_first_party_sets.json" "safemon" "temp") do if exist "%jxb%\%%~A" (rmdir "%jxb%\%%~A" /s /q >nul 2>&1 || del /a /f /q "%jxb%\%%~A" >nul 2>&1)
for /d %%j in ("%jxb%\Default*" "%jxb%\System Profile*" "%jxb%\Guest Profile*" "%jxb%\Profile *") do (
if exist "%%j" (
del /a /f /q "%%j\History*" "%%j\*History" "%%j\Backup*" "%%j\*Backup" "%%j\*.tmp" "%%j\*.bak" "%%j\*.log" "%%j\*.old" "%%j\*Cache" "%%j\*-journal" "%%j\MANIFEST-*" >nul 2>&1
for /d %%i in ("%%j\History*" "%%j\*History" "%%j\Backup*" "%%j\*Backup" "%%j\Download*" "%%j\*Download") do (if exist "%%i" (rmdir /s /q "%%i" >nul 2>&1))
if exist "%%j\Network" (pushd "%%j\Network" 2>nul && if not errorlevel 1 (for %%f in ("Reporting and NEL*") do del /a /f /q "%%f" >nul 2>&1) & popd)
for /d %%i in ("%%j\Cache*" "%%j\*Cache") do (set "Cachea=%%~nxi" & set "Cacheb=0" & for %%e in (%dsc%) do (if "!Cachea!"=="%%e" set "Cacheb=1") & echo "!Cachea!" | findstr /i "\." >nul && set "Cacheb=1" & echo "!Cachea!" | findstr /i "Extension" >nul && set "Cacheb=1" & if "!Cacheb!"=="0" (rmdir /s /q "%%i" >nul 2>&1))
for %%B in ("Articles" "blob_storage" "BrowsingTopicsSiteData" "BrowsingTopicsState" "BudgetDatabase" "commerce_subscription_db" "Conversions" "coupon_db" "Current Session" "Current Tabs" "CURRENT" "DIPS" "discounts_db" "File System" "Feature Engagement Tracker" "GCM Store" "JumpListIcons" "JumpListIconsMostVisited" "JumpListIconsOld" "JumpListIconsRecentClosed" "Last Session" "Last Tabs" "LOG" "MediaDeviceSalts" "Network Action Predictor" "optimization_guide_hint_cache_store" "optimization_guide_model_metadata_store" "optimization_guide_prediction_model_downloads" "Pepper Data" "PersistentOriginTrials" "Platform Notifications" "PreferredApps" "previews_opt_out.db" "parcel_tracking_db" "QuotaManager" "rr" "Storage" "Sessions" "Service Worker" "Session Storage" "Search Logos" "shared_proto_db" "Segmentation Platform" "Site Characteristics Database" "Thumbnails" "Top Sites" "VideoDecodeStats" "Visited Links" "WebStorage" "Web Applications" "Web Applications" "WebrtcVideoStats") do (if exist "%%j\%%~B" (rmdir "%%j\%%~B" /s /q >nul 2>&1 || del /a /f /q "%%j\%%~B" >nul 2>&1))
pushd "%%j\Extensions" 2>nul
if not errorlevel 1 (
for /d %%e in (*) do (
pushd "%%e"
set "maxVersion="
set "maxVersionStr="
for /f "delims=" %%v in ('dir /b /ad-h') do (
set "currentVersion=%%v"
set "currentVersionStr=!currentVersion!"
for /f "tokens=1-4 delims=._" %%a in ("%%v") do (
set "mainPart=%%a.%%b"
set "subPart=%%c_%%d"
)
set "tempCompare=!mainPart!!subPart!"
if "!maxVersionStr!"=="" (
set "maxVersion=%%v"
set "maxVersionStr=!tempCompare!"
) else (
if "!tempCompare!" gtr "!maxVersionStr!" (
set "maxVersion=%%v"
set "maxVersionStr=!tempCompare!"
)
)
)
for /f "delims=" %%o in ('dir /b /ad-h') do (
if not "%%o"=="!maxVersion!" (
rmdir /s /q "%%o" >nul 2>&1
)
)
popd
)
popd
)
for %%k in ("IndexedDB" "databases") do (
pushd "%%j\%%k" 2>nul
if not errorlevel 1 (
for /d %%i in (http*,file*) do (
set "name=%%~nxi"
set "keep=0"
for %%w in (%dsd%) do (
echo "!name!" | findstr /i "%%w" >nul && set "keep=1"
)
if "!keep!"=="0" (
rd /s /q "%%i" >nul 2>&1
del /a /f /q "%%i\*.*" >nul 2>&1
)
)
popd
)
)
)
)
echo.
echo.
echo 清理完成，1秒后退出。
timeout /t 1
exit

复制代码

通用清除垃圾.zip (2.99 KB, 下载次数: 3)

这是我自己写的bat，不管你是多少G

清理完之后都是几百M

支持多用户清理

支持清理浏览器插件升级之后留下的旧版本文件

支持不关浏览器直接清理，因为在清理之前 bat 会自动关闭当前的浏览器

适合任何谷歌内核的浏览器

因为浏览器太多，懒得一个个写，所以写成通用的

适合安装版本或者绿色版本的浏览器

支持清理任何谷歌内核的浏览器，包括EDGE

均已测试，不会误杀

USPY · 发表于 2025-4-24 16:27:28

gh0ul 发表于 2025-4-17 10:58
自带的wipe.bat，最新版的，旧版可能有些毛病

用自带的wipe.bat确实有效果，从3G多减少到1.4G，，用户数据目录还是超过1G

mervinniu · 发表于 2025-4-25 20:44:10

我自己用的这个，放到安装目录下，清理很干净，不会丢失数据。

刘青rain · 发表于前天 09:41

q875720344 发表于 2025-4-24 12:06
这是我自己写的bat，不管你是多少G

清理完之后都是几百M

卧槽，哥们你这个太牛了，我8个G变成1.1G了，而且浏览器功能还能正常用！

q875720344 · 发表于前天 11:15

mervinniu 发表于 2025-4-25 20:44
我自己用的这个，放到安装目录下，清理很干净，不会丢失数据。

不妨告诉你，你压缩包里面的第一个也是我很久之前写的，清理能力其实一般

YmSo · 发表于前天 17:34

我的百分便携文件夹也5.85G了

		自动登录	找回密码
密码			立即注册

[求助] 空间占用6个G怎么清理？

浏览过的版块