[AHK 脚本] 实现 F2 短按复制文件名，长按触发重命名操作

S8F8ry

实现 F2 短按复制文件名，长按触发重命名操作。

AHK v2 版本：

1. ; 实现 F2 短按复制文件名，长按触发重命名操作
   
2. ; 2024-07-09
   
3. #Requires AutoHotkey v2
   
4. #SingleInstance Force
   
5. Persistent
   
6. 
   
7. #HotIf WinActive("ahk_exe explorer.exe")
   
8. 
   
9. $F2:: {
   
10.   if KeyWait("F2", "T0.3") { ; 300ms
    
11.     F2Handler()
    
12.   } else {
    
13.     SendInput "{F2}"
    
14.     KeyWait "F2"
    
15.   }
    
16.   return
    
17. }
    
18. 
    
19. F2Handler() {
    
20.   oldClip := ClipboardAll()
    
21.   A_Clipboard := ""
    
22.   SendInput "^{Ins}"
    
23.   if !ClipWait(1) {
    
24.     ; clipboard wait timeout
    
25.     A_Clipboard := oldClip
    
26.     return
    
27.   }
    
28.   SplitPath A_Clipboard, &outFilename, , , &outNameNoExt
    
29.   if outFilename {
    
30.     A_Clipboard := outFilename
    
31.     ; 或者注释掉上面一行并移除下面一行的注释，则复制时不带文件扩展名
    
32.     ; A_Clipboard := outNameNoExt
    
33.   } else {
    
34.     ; cannot find filename
    
35.     A_Clipboard := oldClip
    
36.   }
    
37. }
    
38. 
    
39. #HotIf

复制代码

AHK v1 版本：

1. ; 实现 F2 短按复制文件名，长按触发重命名操作
   
2. ; 2024-07-09
   
3. #Requires AutoHotkey >=1.1 <1.2
   
4. #SingleInstance Force
   
5. #Persistent
   
6. 
   
7. #IfWinActive ahk_exe explorer.exe
   
8. 
   
9. $F2::
   
10. {
    
11.   KeyWait F2, T0.3 ; 300ms
    
12.   if ErrorLevel
    
13.   {
    
14.     SendInput {F2}
    
15.     KeyWait F2
    
16.   }
    
17.   else
    
18.   {
    
19.     F2Handler()
    
20.   }
    
21.   return
    
22. }
    
23. 
    
24. F2Handler()
    
25. {
    
26.   oldClip := ClipboardAll
    
27.   Clipboard := ""
    
28.   SendInput "^{Ins}"
    
29.   ClipWait 1
    
30.   if ErrorLevel
    
31.   {
    
32.     ; clipboard wait timeout
    
33.     Clipboard := oldClip
    
34.     return
    
35.   }
    
36.   SplitPath Clipboard, outFilename, , , outNameNoExt
    
37.   if outFilename
    
38.   {
    
39.     Clipboard := outFilename
    
40.     ; 或者注释掉上面一行并移除下面一行的注释，则复制时不带文件扩展名
    
41.     ; Clipboard := outNameNoExt
    
42.   }
    
43.   else
    
44.   {
    
45.     ; cannot find filename
    
46.     Clipboard := oldClip
    
47.   }
    
48. }
    
49. 
    
50. #IfWinActive

复制代码

coult3

  赞一个！

问下 $F2 前面的 $ 是什么意思，加和不加有什么区别？
另外ctrl+{Ins}第一次见啊，为什么不用常见的ctrl+c呢，实际上第22行替换成 SendInput "^c" 也没发现问题。

cb112

同问，顺便再问问最后#IfWinActive可以删除吗，最后不用加return吗

S8F8ry

coult3 发表于 2024-7-9 19:33
赞一个！

问下 $F2 前面的 $ 是什么意思，加和不加有什么区别？

加 $ 是由于后续可能会用 SendInput 发送 F2 按键自身，这可以避免触发它自身。Ctrl+Ins / Shift+Ins 是在终端里常用的复制/粘贴操作，只是我单纯用习惯了而已，在这里用 Ctrl+C 应该不会有区别。

S8F8ry

cb112 发表于 2024-7-9 20:22
同问，顺便再问问最后#IfWinActive可以删除吗，最后不用加return吗

"#IfWinActive/#HotIf" 等是用来关闭热键的上下文的，如果你脚本里只有这些代码，那删掉也不会有影响。但是如果你还整合了其他代码，尤其将它们放置此代码之后的话，若没有关闭热键上下文，那它们也只会在 explorer.exe 中才能生效，这通常就不会是预期中的想要的效果了。至于 return，热键的处理块中已经有 retrun 了呀。

cb112

S8F8ry 发表于 2024-7-9 22:19
"#IfWinActive/#HotIf" 等是用来关闭热键的上下文的，如果你脚本里只有这些代码，那删掉也不会有影响。但 ...

v1开头345行的作用是什么，如果把第7行提前作为多段代码大前提，还需要345行吗，位置也不用变吗

S8F8ry

cb112 发表于 2024-7-10 00:33
v1开头345行的作用是什么，如果把第7行提前作为多段代码大前提，还需要345行吗，位置也不用变吗 ...

- "#Requires AutoHotkey >=1.1 <1.2" 是声明脚本仅在 AHK v1 下工作，如果你的电脑上仅安装了 AHK v1 版本，那可以不需要。
- "#SingleInstance Force" 是只允许运行单个脚本实例，如果你再运行一次此脚本则会替换旧实例(只针对此脚本，其他不同脚本是否允许多实例也由它们的内部指令决定)，一般的 AHK 脚本都会加这一行。
- "#Persistent" 是让脚本持续运行，一般的 AHK 脚本也都会加这一行。

这些指令都是放置脚本头部的，如果有整合其他代码的话，除非有特殊需求，例如需要允许运行同一个脚本的多个实例，否则保留即可。或者将 "#IfWinActive ahk_exe explorer.exe ... #IfWinActive" 这部分内容丢到其他脚本尾部也行。

coult3

S8F8ry 发表于 2024-7-9 22:09
加 $ 是由于后续可能会用 SendInput 发送 F2 按键自身，这可以避免触发它自身。Ctrl+Ins / Shift+Ins 是 ...

明白了，感谢超版，我也试着写了一个。

F2说：SplitPath是个好函数，但我用原生ctrl+c和ctrl+a，缺点是会有一闪而过的蓝色。

1. ; 实现 F2 短按复制文件名，长按触发重命名操作
   
2. #Requires AutoHotkey v2.0
   
3. #SingleInstance
   
4. 
   
5. #HotIf WinActive("ahk_exe explorer.exe")
   
6. 
   
7. $F2:: {
   
8.   if KeyWait("F2", "T0.3") { ;300ms
   
9.     Send "{F2}"
   
10.         send "^a"
    
11.         send "^c"
    
12.         send "{ESC}"
    
13.   } else {
    
14.     SendInput "{F2}"
    
15.     KeyWait "F2"
    
16.   }
    
17.   return
    
18. }
    
19. 
    
20. #HotIf

复制代码

coult3

F2说：SplitPath是个好函数，但我选择 StrSplit

1. ; 实现 F2 短按复制文件名，长按触发重命名操作
   
2. #Requires AutoHotkey v2.0
   
3. #SingleInstance
   
4. 
   
5. #HotIf WinActive("ahk_exe explorer.exe")
   
6. 
   
7. $F2:: {
   
8.   if KeyWait("F2", "T0.3") { ;300ms
   
9.         A_Clipboard := ""
   
10.         send "^c"
    
11.         ClipWait
    
12.         Filename := StrSplit(A_Clipboard, "")  
    
13.         A_Clipboard := Filename[-1]
    
14.         ;MsgBox Filename[-1]
    
15.   } else {
    
16.     SendInput "{F2}"
    
17.     KeyWait "F2"
    
18.   }
    
19.   return
    
20. }
    
21. 
    
22. #HotIf
    
23. 
    
24. ;用 ([^\\]+)$ 匹配末尾的文件名
    
25. ;https://stackoverflow.com/a/2655902
    
26. ;https://wyagd001.github.io/v2/docs/lib/RegExMatch.htm#ExOutputVar
    
27. ;https://wyagd001.github.io/v2/docs/lib/Array.htm

复制代码

F2说：SplitPath是个好函数，但我选择 正则 RegExMatch

1. ; 实现 F2 短按复制文件名，长按触发重命名操作
   
2. #Requires AutoHotkey v2.0
   
3. #SingleInstance
   
4. 
   
5. #HotIf WinActive("ahk_exe explorer.exe")
   
6. 
   
7. $F2:: {
   
8.   if KeyWait("F2", "T0.3") { ;300ms
   
9.         A_Clipboard := ""
   
10.         send "^c"
    
11.         ClipWait
    
12.         regex := "([^\\]+)$"
    
13.         RegExMatch(A_Clipboard, regex, &Filename)
    
14.         A_Clipboard := Filename[1]
    
15.   } else {
    
16.     SendInput "{F2}"
    
17.     KeyWait "F2"
    
18.   }
    
19.   return
    
20. }
    
21. 
    
22. #HotIf
    
23. 
    
24. ;用 ([^\\]+)$ 匹配末尾的文件名
    
25. ;https://stackoverflow.com/a/2655902
    
26. ;https://wyagd001.github.io/v2/docs/lib/RegExMatch.htm#ExOutputVar

复制代码

最后贴一个 F2 复制选中文件的路径：

1. #Requires AutoHotkey v2.0
   
2. #SingleInstance
   
3. 
   
4. F2::
   
5. {
   
6.         Send "^c"
   
7.         Sleep 200
   
8.         ;将任何复制的文件, HTML 或其他格式的文本转换为纯文本.
   
9.         ;https://wyagd001.github.io/v2/docs/lib/A_Clipboard.htm
   
10.         A_Clipboard := A_Clipboard
    
11.         return
    
12. }

复制代码